Array класс

Доступность

Flash Player 5 (стал "полноценным" в Flash Player 6, со значительным расширением возможностей использования).

Описание

Класс Array позволяет Вам работать с массивами. Массив - объект, свойства которого идентифицируются порядковым номером, представляющим их позицию в массиве. Этот номер называют index /индекс/. Первый элемент массива всегда имеет индекс [0], второй элемент [1], и так далее. Для создания объекта Array, используется конструктор new Array(). Доступ к элементам массива осуществляется с помощью оператора ([]) .

В следующем примере, my_array состоит из четырёх названий месяца :

var my_array:Array = new Array();
my_array[0] = "January";
my_array[1] = "February";
my_array[2] = "March";
my_array[3] = "April";

Таблица методов класса Array

Метод	Описание
`Array.concat()`	Соединяет элементы (последовательности массивов), и возвращает их, уже как новый массив.
`Array.join()`	Объединяет все элементы массива в строку.
`Array.pop()`	Удаляет последний элемент массива и возвращает его значение.
`Array.push()`	Добавляет один или больше элементов в конец массива и возвращает длину нового массива.
`Array.reverse()`	Реверсирует элементы массива.
`Array.shift()`	Удаляет первый элемент массива и возвращает его значение.
`Array.slice()`	Извлекает из массива часть и возвращает ее, как новый массив.
`Array.sort()`	Сортирует массив.
`Array.sortOn()`	Сортирует массив однотипных объектов.
`Array.splice()`	Добавляет и/или/ удаляет элементы из массива.
`Array.toString()`	Возвращает строковое значение элементов объекта Array.
`Array.unshift()`	Добавляет один или больше элементов в начало массива и возвращает длину нового массива.

Таблица свойств класса Array

Свойство	Описание
`Array.length`	Неотрицательное целое число, определяющее число элементов массива.

Конструктор класса Array

Доступность

Flash Player 5.

Синтаксис

new Array() : Array
new Array(length:Number) : Array
new Array(element0, element1, element2,...elementN) : Array

Параметры

length Неотрицательное целое число, определяющее число элементов массива.

element0...elementN Список двух или более элементов. Элементы могут иметь тип Boolean, Number, String, Object, или Array. Первый элемент массива всегда имеет индекс 0.

Примечание: Если конструктору Array передаётся только один числовой параметр, предполагается, что это длина length массива; при этом параметр конвертируется в целое число с помощью функции Integer().

Возвращает

Ссылка на объект Array.

Описание

Конструктор; позволяет Вам создавать массив. Вы можете использовать конструктор, для создания различных типов массивов: пустой массив, массив с определенной длиной, с элементами неопределённых значений, или массив, элементы которого имеют определенные значения.

Использование 1: Если Вы не определяете ни одного параметра, создаётся массив с длиной 0 /пустой массив/.

Использование 2: Если Вы определяете только длину, создаётся массив с числом length элементов. Каждому элементу будет присвоено значение undefined.

Использование 3: Если Вы используете параметры element с определёнными значениями, создаётся массив с элементами, имеющими определённое значение.

Пример

Использование 1: В следующем примере создаётся новый пустой/с длиной 0/ массив :

var my_array:Array = new Array();
trace(my_array.length); // traces 0

Использование 2: Пример создания нового массива, с длиной 4 :

var my_array:Array = new Array(4);
trace(my_array.length); // возвращает 4
trace(my_array[0]); // возвращает undefined
if (my_array[0] == undefined) { // undefined не берётся в кавычки
  trace("undefined is a special value, not a string");
} // выводится: undefined is a special value, not a string

Использование 3: Пример создания массива go_gos_array , с длиной 5:

var go_gos_array:Array = new Array("Belinda", "Gina", "Kathy", "Charlotte", "Jane");
trace(go_gos_array.length); // возвращает 5
trace(go_gos_array.join(", ")); // перечисление элементов

Элементы массива go_gos_array определены, аналогично тому, как показано в следующем примере :

go_gos_array[0] = "Belinda";
go_gos_array[1] = "Gina";
go_gos_array[2] = "Kathy";
go_gos_array[3] = "Charlotte";
go_gos_array[4] = "Jane";

Следующий код добавляет шестой элемент массива go_gos_array и переопределяет его второй элемент :

go_gos_array[5] = "Donna";
go_gos_array[1] = "Nina"
trace(go_gos_array.join(" + "));
// Возвращает Belinda + Nina + Kathy + Charlotte + Jane + Donna

См.также

Array.length, [] (array access)

Посмотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление